《案例精解企业级网络构建》赠书活动开始啦！　最新活动：“Web安全大家谈”有奖征文

Visual Basic 2005——如何在DataGridView控件的储存格中同时显示出文字与图片

2006-09-27 11:43:47

　标签：图片文字 Visual Basic DataGridView　　　[推送到技术圈]

上次有读者说我写得太简单，那么我们今天就写个难一点的吧！很多用户询问，如何如图1所示，在DataGridView控件的储存格中同时显示出图片与文字。

图1

DataGridView控件并没有内建任何功能来让您在同一个储存格中显示出图片与文字。解决之道，是通过CellPaint等事件来完成自订的绘制作业。

以下我们建立一个衍生自DataGridViewTextBoxColumn的用户自订数据行类别，藉此于储存格内的文字旁边绘制一个图片。我们使用DataGridViewCellStyle.Padding属性来调整文字位置并重写Paint方法以便绘制一个图片：

Public Class TextAndImageColumn
    Inherits DataGridViewTextBoxColumn

    Private _imageValue As Image
    Private _imageSize As Size

    Public Sub New()
        MyBase.New()
        Me.CellTemplate = New TextAndImageCell
        Me.DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight
    End Sub

    Public Property Image() As Image
        Get
            Return Me._imageValue
        End Get
        Set(ByVal value As Image)
            Me._imageValue = value
            Me._imageSize = value.Size
            If Me.InheritedStyle IsNot Nothing Then
                Dim inheritedPadding As Padding = Me.InheritedStyle.Padding
                Me.DefaultCellStyle.Padding = New Padding( _

ImageSize.Width, inheritedPadding.Top, _

                  inheritedPadding.Right, inheritedPadding.Bottom)
            End If
        End Set
    End Property

    Private ReadOnly Property TextAndImageCellTemplate() As TextAndImageCell
        Get
            Return CType(Me.CellTemplate, TextAndImageCell)
        End Get
    End Property

    Friend ReadOnly Property ImageSize() As Size
        Get
            Return ImageSize
        End Get
    End Property

    Public Overrides Function Clone() As Object
        Dim c As TextAndImageColumn = CType(MyBase.Clone, TextAndImageColumn)
        c._imageValue = Me._imageValue
        c._imageSize = Me.ImageSize
        Return c
    End Function
End Class

Public Class TextAndImageCell
    Inherits DataGridViewTextBoxCell

    Private imageValue As Image
    Private imageSize As Size

    Public Property Image() As Image
        Get
            If ((Me.OwningColumn Is Nothing) _
                      OrElse (Me.OwningTextAndImageColumn Is Nothing)) Then
                Return imageValue
            ElseIf (Me.imageValue IsNot Nothing) Then
                Return Me.imageValue
            Else
                Return Me.OwningTextAndImageColumn.Image
            End If
        End Get
        Set(ByVal value As Image)
            If Not Me.imageValue.Equals(value) Then
                Me.imageValue = value
                Me.imageSize = value.Size
                Dim inheritedPadding As Padding = Me.InheritedStyle.Padding
                Me.Style.Padding = New Padding( _
                  imageSize.Width, inheritedPadding.Top, _
                  inheritedPadding.Right, inheritedPadding.Bottom)
            End If
        End Set
    End Property

    Private ReadOnly Property OwningTextAndImageColumn() As TextAndImageColumn
        Get
            Return CType(Me.OwningColumn, TextAndImageColumn)
        End Get
    End Property

    Public Overrides Function Clone() As Object
        Dim c As TextAndImageCell = CType(MyBase.Clone, TextAndImageCell)
        c.imageValue = Me.imageValue
        c.imageSize = Me.imageSize
        Return c
    End Function

    Protected Overrides Sub Paint(ByVal graphics As Graphics, _

ByVal clipBounds As Rectangle, ByVal cellBounds As Rectangle, _

ByVal rowIndex As Integer, _

ByVal cellState As DataGridViewElementStates, _

ByVal value As Object, ByVal formattedValue As Object, _

ByVal errorText As String, ByVal cellStyle As DataGridViewCellStyle, _

ByVal advancedBorderStyle As DataGridViewAdvancedBorderStyle, _

ByVal paintParts As DataGridViewPaintParts)

MyBase.Paint(graphics, clipBounds, cellBounds, rowIndex, _

cellState, value, formattedValue, errorText, cellStyle, _

        advancedBorderStyle, paintParts)
        If (Not (Me.Image) Is Nothing) Then
            Dim container As System.Drawing.Drawing2D.GraphicsContainer = _

              graphics.BeginContainer
            graphics.SetClip(cellBounds)
            graphics.DrawImageUnscaled(Me.Image, cellBounds.Location)
            graphics.EndContainer(container)
        End If
    End Sub
End Class

本文出自 “章立民” 博客，转载请与作者联系！

上一篇 VIsual Basic 2005 - 如何使用 SqlBulkCopy 对..　　下一篇 Visual C#2005——如何使用ToArray方法返回一..

类别：VisualBasic2005 ┆ 技术圈() ┆ 阅读() ┆ 评论() ┆推送到技术圈 ┆返回首页

相关文章

文章评论

[匿名]51CTO游客

2007-12-06 10:35:23

章老师，您好！我这个DAtagridview属性IntFigs没法和Number的IntFigs连接起来，请您帮我看一个，谢谢
Imports System
Imports System.Windows.Forms
'========================================================================================
' NumbericBox单元列
'========================================================================================
Public Class NumericBoxColumn
Inherits DataGridViewColumn

Public Sub New()
MyBase.New(New NumericBoxCell())
End Sub

'获取或设置用于创建新单元格的模板。
Public Overrides Property CellTemplate() As DataGridViewCell
Get
Return MyBase.CellTemplate
End Get
Set(ByVal value As DataGridViewCell)

' Ensure that the cell used for the template is a CalendarCell.
If (value IsNot Nothing) AndAlso Not value.GetType().IsAssignableFrom(GetType(NumericBoxCell)) Then
Throw New InvalidCastException("Must be a CalendarCell")
End If
MyBase.CellTemplate = value
End Set
End Property
'内部変数
Private mValue As Double = 0
Private mIntFigs As Integer = 1
Private mDecFigs As Integer = 0
Private mFormatString As String = "0"
Private mMaxValue As Double = 1.7976931348623157E+308
Private mMinValue As Double = -1.7976931348623157E+308

Public Property IntFigs() As Integer
Get
Return mIntFigs
End Get
Set(ByVal value As Integer)
mIntFigs = value
End Set
End Property

' Override the Clone method so that the Enabled property is copied.
Public Overrides Function Clone() As Object
Dim Cell As NumericBoxColumn = CType(MyBase.Clone(), NumericBoxColumn)
Cell.IntFigs = Me.IntFigs
Return Cell
End Function
End Class
'========================================================================================
' NumbericBox单元格
'========================================================================================
'显示 DataGridView 控件中的可编辑文本信息。
Public Class NumericBoxCell
Inherits DataGridViewTextBoxCell

Public Sub New()
' Use the short date format.
'Me.Style.Format = "#"
Me.IntFigs = 5
End Sub

'附加并初始化寄宿的编辑控件。
Public Overrides Sub InitializeEditingControl(ByVal rowIndex As Integer, ByVal initialFormattedValue As Object, ByVal dataGridViewCellStyle As DataGridViewCellStyle)

' Set the value of the editing control to the current cell value.
MyBase.InitializeEditingControl(rowIndex, initialFormattedValue, dataGridViewCellStyle)

Dim ctl As CalendarEditingControl = CType(DataGridView.EditingControl, CalendarEditingControl)
ctl.Value = CDbl((Me.Value))
ctl.IntFigs = Me.IntFigs
End Sub

'获取单元格的寄宿编辑控件的类型。
Public Overrides ReadOnly Property EditType() As Type
Get
' Return the type of the editing contol that CalendarCell uses.
Return GetType(CalendarEditingControl)
End Get
End Property

'提供值类型的基类。
Public Overrides ReadOnly Property ValueType() As Type
Get
' Return the type of the value that CalendarCell contains.
Return GetType(Double)
End Get
End Property

'获取创建新行时使用的默认值。
Public Overrides ReadOnly Property DefaultNewRowValue() As Object
Get
' Use the current date and time as the default value.
Return 0
End Get
End Property
'------------------------------------------------------------
Private mValue As Double = 0
Private mIntFigs As Integer = 1
Private mDecFigs As Integer = 0
Private mFormatString As String = "0"
Private mMaxValue As Double = 1.7976931348623157E+308
Private mMinValue As Double = -1.7976931348623157E+308

Public Property IntFigs() As Integer
Get
Return mIntFigs
End Get
Set(ByVal value As Integer)
mIntFigs = value
End Set
End Property
' Override the Clone method so that the Enabled property is copied.
Public Overrides Function Clone() As Object
Dim Cell As NumericBoxCell = CType(MyBase.Clone(), NumericBoxCell)
Cell.IntFigs = Me.IntFigs
Return Cell
End Function

'-------------------------------------------------
End Class

'========================================================================================
' NumbericBox控件
'========================================================================================
Class CalendarEditingControl
Inherits NumericBox
Implements IDataGridViewEditingControl

Private dataGridViewControl As DataGridView
Private valueIsChanged As Boolean = False
Private rowIndexNum As Integer
'初始格式化为0
Public Sub New()
'Me.FormatString = "0"
End Sub

'设置DataGridView格式化后的值
Public Property EditingControlFormattedValue() As Object _
Implements IDataGridViewEditingControl.EditingControlFormattedValue

Get
Return Me.Text
End Get

Set(ByVal value As Object)
If TypeOf value Is String Then
Me.Value = CDbl((value))
End If
End Set

End Property

'检索单元格的格式化值。

Public Function GetEditingControlFormattedValue(ByVal context As DataGridViewDataErrorContexts) As Object _
Implements IDataGridViewEditingControl.GetEditingControlFormattedValue

Return Me.Text

End Function

'设置背景,字体
Public Sub ApplyCellStyleToEditingControl(ByVal dataGridViewCellStyle As DataGridViewCellStyle) _
Implements IDataGridViewEditingControl.ApplyCellStyleToEditingControl

Me.Font = dataGridViewCellStyle.Font
Me.ForeColor = dataGridViewCellStyle.ForeColor
Me.BackColor = dataGridViewCellStyle.BackColor

End Sub

'获取或设置所属单元格的父行的索引。
Public Property EditingControlRowIndex() As Integer _
Implements IDataGridViewEditingControl.EditingControlRowIndex

Get
Return rowIndexNum
End Get
Set(ByVal value As Integer)
rowIndexNum = value
End Set

End Property

'确定指定的键是应由编辑控件处理的常规输入键，还是应由 DataGridView 处理的特殊键。
Public Function EditingControlWantsInputKey(ByVal key As Keys, ByVal dataGridViewWantsInputKey As Boolean) As Boolean _
Implements IDataGridViewEditingControl.EditingControlWantsInputKey

' Let the DateTimePicker handle the keys listed.
Select Case key And Keys.KeyCode
Case Keys.Left, Keys.Up, Keys.Down, Keys.Right, _
Keys.Home, Keys.End, Keys.PageDown, Keys.PageUp

Return True

Case Else
Return False
End Select

End Function

'准备当前选中的单元格以进行编辑。
Public Sub PrepareEditingControlForEdit(ByVal selectAll As Boolean) _
Implements IDataGridViewEditingControl.PrepareEditingControlForEdit

' No preparation needs to be done.

End Sub

'获取一个值，指示是否需要在每次值更改时重新定位单元格内容。
Public ReadOnly Property RepositionEditingControlOnValueChange() As Boolean _
Implements IDataGridViewEditingControl.RepositionEditingControlOnValueChange

Get
Return False
End Get

End Property

'获取或设置包含组合框控件的 DataGridView
Public Property EditingControlDataGridView() As DataGridView _
Implements IDataGridViewEditingControl.EditingControlDataGridView

Get
Return dataGridViewControl
End Get
Set(ByVal value As DataGridView)
dataGridViewControl = value
End Set

End Property

'获取或设置一个值，该值指示编辑控件的值是否与承载单元格的值不同。
Public Property EditingControlValueChanged() As Boolean _
Implements IDataGridViewEditingControl.EditingControlValueChanged

Get
Return valueIsChanged
End Get
Set(ByVal value As Boolean)
valueIsChanged = value
End Set

End Property
'设置光标
Public ReadOnly Property EditingControlCursor() As Cursor _
Implements IDataGridViewEditingControl.EditingPanelCursor

Get
Return MyBase.Cursor
End Get

End Property

'引发已实现的 ValueChanged 事件
Public Overrides Sub OnValueChanged(ByVal eventargs As EventArgs)
' Notify the DataGridView that the contents of the cell have changed.
valueIsChanged = True
Me.EditingControlDataGridView.NotifyCurrentCellDirty(True)
MyBase.OnValueChanged(eventargs)
End Sub

End Class

昵称：
验证码：		点击图片可刷新验证码　　博客过2级，无需填写验证码
内容：